I suspect you will have to use the pre-calculated effect size approach.  Here is an example using the 7 studies shown on this Stata page:

https://www.stata.com/new-in-stata/meta-analysis-prevalence-proportions/

I chose to use the logit transformation.  I could not find logit() and invlogit() functions, so I had to roll my own.  Here's the code.

NEW FILE.
DATASET CLOSE ALL.
DATA LIST LIST / Study N events (3F8.0).
BEGIN DATA 
1 14200 1178
2 51000 4641
3 86400 3974
4 68000 2856
5 43400 1519
6 15500  604
7 54500 5341
END DATA.
DATASET NAME raw.

COMPUTE nonevents = N - events.
COMPUTE p = events/N.
COMPUTE q = 1-p.
COMPUTE y = ln(p/q).
COMPUTE sey = SQRT(1/events + 1/nonevents).
VARIABLE LABELS 
    y "Y = logit(p)"
    sey "SE(Y)"
.
LIST y sey.

* OMS.
DATASET DECLARE  PooledEst.
OMS
  /SELECT TABLES
  /IF COMMANDS=['Meta ES Continuous'] SUBTYPES=['Effect Size Estimates']
  /DESTINATION FORMAT=SAV NUMBERED=TableNumber_
   OUTFILE='PooledEst' VIEWER=YES.
* OMS.
DATASET DECLARE  IndStud.
OMS
  /SELECT TABLES
  /IF COMMANDS=['Meta ES Continuous'] SUBTYPES=['Effect Size Estimates for Individual Studies']
  /DESTINATION FORMAT=SAV NUMBERED=TableNumber_
   OUTFILE='IndStud' VIEWER=YES.

META ES CONTINUOUS
  /DATA ES=y  SE=sey  ID=Study  
  /CRITERIA CILEVEL=95 SCOPE=AVAILABLE
   CLASSMISSING=EXCLUDE MAXITER=100 MAXSTEP=5 
    CONVERGENCE=0.000001
  /INFERENCE MODEL=RANDOM ESTIMATE=REML ADJUSTSE=NONE
  /PRINT  INDIVIDUAL
  /FORESTPLOT  ADDCOLS=N events POSITION=RIGHT
   ANNOTATIONS=HOMOGENEITY HETEROGENEITY TEST.

OMSEND.

DATASET ACTIVATE IndStud WINDOW = FRONT.
* Apply inverse-logit transformation: exp(x)/(1+exp(x)).
COMPUTE p = EXP(EffectSize)/(1+EXP(EffectSize)).
COMPUTE lb = EXP(Lower)/(1+EXP(Lower)).
COMPUTE ub = EXP(Upper)/(1+EXP(Upper)).
FORMATS p lb ub (F8.3).
LIST p lb ub.

DATASET ACTIVATE PooledEst.
* Apply inverse-logit transformation: exp(x)/(1+exp(x)).
COMPUTE p = EXP(EffectSize)/(1+EXP(EffectSize)).
COMPUTE lb = EXP(Lower)/(1+EXP(Lower)).
COMPUTE ub = EXP(Upper)/(1+EXP(Upper)).
FORMATS p lb ub (F8.3).
LIST p lb ub.
* This pooled estimate matches the result 
* I get using Stata. 

Here are the results from that last LIST:

       p       lb       ub 
 
    .057     .041     .079 

For comparison, here are the results from Stata.  You'll have to display in a fixed font to make it more readable.

. meta summarize, transform(invlogit) 

  Effect-size label: Logit proportion
        Effect size: _meta_es
          Std. err.: _meta_se

Meta-analysis summary                     Number of studies =      7
Random-effects model                      Heterogeneity:
Method: REML                                          tau2 =  0.2220
                                                    I2 (%) =   99.82
                                                        H2 =  560.84

--------------------------------------------------------------------
            Study |     Proportion    [95% conf. interval]  % weight
------------------+-------------------------------------------------
          Study 1 |          0.083       0.079       0.088     14.27
          Study 2 |          0.091       0.089       0.094     14.31
          Study 3 |          0.046       0.045       0.047     14.31
          Study 4 |          0.042       0.041       0.044     14.30
          Study 5 |          0.035       0.033       0.037     14.28
          Study 6 |          0.039       0.036       0.042     14.22
          Study 7 |          0.098       0.096       0.101     14.31
------------------+-------------------------------------------------
  invlogit(theta) |          0.057       0.041       0.079
--------------------------------------------------------------------
Test of theta = 0: z = -15.70                    Prob > |z| = 0.0000
Test of homogeneity: Q = chi2(6) = 3474.75         Prob > Q = 0.0000

I hope this helps.