Hello Elisabeth. I had an old syntax file showing this example from the late David Howell:
https://www.uvm.edu/~statdhtx/StatPages/Missing_Data/MissingDataSPSS.html
So to verify that UNIANOVA does generate pooled estimates, I added a few lines to estimate Howell's model via UNIANOVA. Here are the two commands:
DATASET ACTIVATE midata.
REGRESSION
/SELECT=Imputation_ GE 1
/MISSING LISTWISE
/STATISTICS COEFF OUTS CI(95) R ANOVA
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT Totbpt
/METHOD=ENTER SexP DeptP AnxtP DeptS AnxtS
/SAVE SRESID.
* 24-Jul-2024: Estimate the same model via UNIANOVA,
* and include DESCRIPTIVES on the PRINT sub-command
* to address some of the issues raised here:
* https://community.ibm.com/community/user/ai-datascience/discussion/anova-using-multiple-imputation
.
UNIANOVA Totbpt WITH SexP DeptP AnxtP DeptS AnxtS
/PRINT= DESCRIPTIVE PARAMETER
/CRITERIA=ALPHA(.05)
/DESIGN=SexP DeptP AnxtP DeptS AnxtS.
I do get pooled estimates of the model coefficients in the UNIANOVA output, and they match the ones I get in the REGRESSION output. I was going to upload an image to show you the two outputs, but the Upload File feature does not seem to work. I could not even upload my syntax--but I'll paste it below so you can try it yourself.
So, this leaves me wondering if the problem is that you not activated the dataset with the multiply imputed data before you run your UNIANOVA command. Is that possible? Or have you somehow deleted the Imputation_ variable? Those are the only two things I can think of that would cause problem you are having.
Cheers,
Bruce
PS- Here is my updated syntax for that Dave Howell example.
* -----------------------------------------------------------------------------.
* Date: 9-Apr-2020.
* Modified: 24-Jul-2024.
* Bruce Weaver, bweaver@lakeheadu.ca.
* Dave Howell's multiple imputation example from URL below (with minor tweaks).
* https://www.uvm.edu/~statdhtx/StatPages/Missing_Data/MissingDataSPSS.html .
* -----------------------------------------------------------------------------.
NEW FILE.
DATASET CLOSE ALL.
DATA LIST LIST / SexP DeptP AnxtP GSItP DeptS AnxtS SexChild Totbpt (8F5.0).
BEGIN DATA
2 50 52 52 44 41 42 -9 -9
1 65 55 57 73 68 71 1 60
1 57 67 61 67 63 65 2 45
2 61 64 57 60 59 62 1 48
2 61 52 57 44 50 50 1 58
1 53 55 53 70 70 69 -9 -9
2 64 59 60 -9 -9 -9 -9 -9
1 53 50 50 42 38 33 2 52
2 42 38 39 44 41 45 -9 -9
2 61 61 55 44 50 42 1 51
1 44 50 42 42 38 43 -9 -9
2 57 55 51 44 41 35 -9 -9
-9 -9 -9 -9 57 52 57 2 65
2 70 59 66 -9 -9 -9 1 61
2 57 61 52 53 59 53 2 49
1 53 55 59 -9 -9 -9 -9 -9
2 61 46 56 -9 -9 -9 2 33
2 61 55 58 -9 -9 -9 -9 -9
2 63 63 63 -9 -9 -9 1 64
2 42 38 39 71 69 67 -9 -9
2 57 61 57 78 55 64 1 46
2 42 52 48 44 41 42 -9 -9
2 42 55 54 -9 -9 -9 -9 -9
2 42 38 49 44 41 42 -9 -9
2 42 55 54 44 55 50 -9 -9
1 44 55 53 61 52 52 -9 -9
2 50 52 48 -9 -9 -9 -9 -9
-9 -9 -9 -9 61 68 61 -9 -9
2 50 38 45 44 50 50 2 43
2 42 38 43 -9 -9 -9 1 33
2 54 38 51 73 74 66 -9 -9
2 66 61 63 80 80 80 1 56
2 50 46 51 -9 -9 -9 -9 -9
1 53 59 57 50 63 61 2 60
2 62 52 57 -9 -9 -9 2 49
2 63 70 61 44 50 48 2 55
-9 -9 -9 -9 57 55 55 1 68
2 54 63 56 53 59 48 1 55
2 54 52 57 57 59 59 -9 -9
2 57 52 51 -9 -9 -9 1 48
1 53 55 57 42 46 43 -9 -9
1 65 55 64 54 46 52 1 62
1 71 80 80 42 46 49 1 62
1 44 64 55 65 61 61 -9 -9
2 50 52 48 44 50 55 1 44
2 71 63 69 65 50 52 2 63
2 42 52 48 -9 -9 -9 -9 -9
2 42 61 56 -9 -9 -9 -9 -9
1 44 59 53 50 52 43 -9 -9
2 42 38 48 -9 -9 -9 -9 -9
2 62 63 60 44 41 50 -9 -9
2 54 46 52 50 63 55 -9 -9
-9 -9 -9 -9 64 59 60 2 33
1 69 64 61 -9 -9 -9 -9 -9
2 68 66 63 67 70 65 -9 -9
2 50 46 48 44 41 45 -9 -9
2 42 38 43 44 41 35 -9 -9
1 44 59 48 42 46 39 2 41
2 42 46 51 53 41 42 -9 -9
2 50 55 54 57 50 53 -9 -9
2 54 55 63 -9 -9 -9 1 65
-9 -9 -9 -9 65 64 60 1 61
-9 -9 -9 -9 57 55 54 -9 -9
2 50 61 55 53 64 65 2 57
2 57 70 71 60 67 58 1 61
2 64 68 66 44 64 48 2 67
2 78 75 80 71 64 65 -9 -9
2 62 55 54 67 64 66 -9 -9
2 42 55 54 44 50 45 1 39
2 42 55 55 -9 -9 -9 -9 -9
2 63 64 63 -9 -9 -9 2 59
2 73 75 80 -9 -9 -9 2 77
2 54 55 57 44 41 45 2 30
2 50 55 60 -9 -9 -9 -9 -9
2 -9 -9 -9 50 55 45 -9 -9
2 42 38 43 65 78 72 2 49
2 61 55 55 -9 -9 -9 2 62
1 -9 -9 -9 -9 -9 -9 -9 -9
2 61 59 61 57 63 58 1 59
2 54 59 57 -9 -9 -9 -9 -9
2 67 52 62 -9 -9 -9 -9 -9
2 57 68 57 -9 -9 -9 1 39
2 63 61 66 71 74 72 1 68
2 63 59 61 -9 -9 -9 -9 -9
2 -9 -9 -9 -9 -9 -9 -9 -9
2 42 38 45 60 67 57 -9 -9
2 50 52 48 -9 -9 -9 -9 -9
-9 -9 -9 -9 44 55 45 -9 -9
1 73 74 72 50 46 55 -9 -9
END DATA.
DATASET NAME rawdata.
MISSING VALUES all (-9).
*Impute Missing Data Values.
DATASET DECLARE midata.
MULTIPLE IMPUTATION SexP DeptP AnxtP AnxtS Totbpt DeptS GSItP SexChild
/IMPUTE METHOD=AUTO NIMPUTATIONS=5 MAXPCTMISSING=NONE
/MISSINGSUMMARIES NONE
/IMPUTATIONSUMMARIES MODELS DESCRIPTIVES
/OUTFILE IMPUTATIONS=midata .
DATASET ACTIVATE midata.
REGRESSION
/SELECT=Imputation_ GE 1
/MISSING LISTWISE
/STATISTICS COEFF OUTS CI(95) R ANOVA
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT Totbpt
/METHOD=ENTER SexP DeptP AnxtP DeptS AnxtS
/SAVE SRESID.
* NOTE: I'm not sure why DH included that SELECT line.
* The pooled results are the same with or without that line.
* E.g., notice that the pooled results using UNIANOVA below,
* with no exclusion of the original dataset, are the same.
* 24-Jul-2024: Estimate the same model via UNIANOVA,
* and include DESCRIPTIVES on the PRINT sub-command
* to address some of the issues raised here:
* https://community.ibm.com/community/user/ai-datascience/discussion/anova-using-multiple-imputation
.
UNIANOVA Totbpt WITH SexP DeptP AnxtP DeptS AnxtS
/PRINT= DESCRIPTIVE PARAMETER
/CRITERIA=ALPHA(.05)
/DESIGN=SexP DeptP AnxtP DeptS AnxtS.
* DESCRIPTIVES command supports pooling:
* https://www.ibm.com/support/knowledgecenter/el/SSLVMB_23.0.0/spss/mva/mi_analysis.html#mi_analysis .
* DESCRIPTIVES with default settings.
DESCRIPTIVES all.
* Notice that only the MEAN is reported in the pooled section of the table.
* Apparently, a pooled estimate of the SD cannot be computed.
* DESCRIPTIVES with SEMEAN.
DESCRIPTIVES all /STATISTICS=MEAN SEMEAN.
* A pooled estimate of SEMEAN is reported.
* -----------------------------------------------------------------------------.
------------------------------
Bruce Weaver
------------------------------
Original Message:
Sent: Tue July 16, 2024 01:31 PM
From: Elisabeth Mistur
Subject: ANOVA using Multiple Imputation
I have successfully created a multiple imputation dataset (Five imputations were performed using default settings in SPSS version 29.0.0, and the results were automatically pooled for analyses using Rubin's rules). Using the imputed dataset, I ran paired sample T-tests and successfully obtained pooled inferential statistics for these T-tests. My issue is in running an ANOVA using the same imputed dataset; the output provides descriptive and inferential stats for the 5 separate imputations, but only provides descriptive stats for pooled data. No SPSS warning or issue is stated in the output. I need pooled inferential stats (F and p-values), and cannot find how to obtain them. From what I have read, it seems that SPSS version 29.0.0 should be able to provide pooled inferential statistics for an ANOVA although older versions could not. I have been unable to identify the problem as to why the output is not providing these statistics. Here is my syntax:
* Encoding: UTF-8.
**One-Way ANOVAS of change scores ETHNICITY
UNIANOVA PHQ_post_minus_pre BY Short_Ethnicity
/METHOD=SSTYPE(3)
/INTERCEPT=INCLUDE
/EMMEANS=TABLES(Short_Ethnicity)
/PRINT ETASQ DESCRIPTIVE HOMOGENEITY OPOWER
/CRITERIA=ALPHA(.05)
/DESIGN=Short_Ethnicity.
#For multiple imputation
UNIANOVA PHQ_post_minus_pre BY Short_Ethnicity
/MISSING=INCLUDE
/PRINT= DESCRIPTIVE PARAMETER
/CRITERIA=ALPHA(.05)
/DESIGN=Short_Ethnicity.
------------------------------
Elisabeth Mistur
------------------------------